Charakter

仮のものになりますが、現在使っている中間素材用マクロと、新式制作用マクロになります。

　以前紹介した装備の場合、食事はロネークステーキHQで統一し、中間素材は薬なしで１００％、新式は薬が必要です。マイスターなら薬が省略できます。作業数値に余裕があるので最適化できそうですが、言い換えるとステータスが多少違っても使えるということで、まぁまぁ便利なのではと思います。行数も短めになっています。

　最終品質は前紹介した装備だと14588になり、不足品質は4112です。アクセ、手頭足は薬と９９素材をHQにすれば制作可能で、体と脚と武器は4つHQが必要になるため、マイスターを活用するなどして何とかしたいところです…


■装備　※この装備ではなくても大丈夫なので参考に
https://jp.finalfantasyxiv.com/lodestone/character/40431847/blog/5485822/



【中間素材】食事：ロネークステーキHQ、薬なし、マイスターなし
/ac "確信" <wait.3>
/ac "マニピュレーション" <wait.2>
/ac "ヴェネレーション" <wait.2>
/ac "長期倹約" <wait.2>
/ac "下地作業" <wait.3>
/ac "精密作業" <wait.3>
/ac "精密作業" <wait.3>
/ac "イノベーション" <wait.2>
/ac "下地加工" <wait.3>
/ac "下地加工" <wait.3>
/ac "下地加工" <wait.3>
/ac "下地加工" <wait.3>
/ac "マスターズメンド" <wait.3>
/ac "グレートストライド" <wait.2>
/echo Macro #1 complete <se.1>

/ac "イノベーション" <wait.2>
/ac "下地加工" <wait.3>
/ac "グレートストライド" <wait.2>
/ac "ビエルゴの祝福" <wait.3>
/ac "作業" <wait.3>
/echo Macro #2 complete <se.14>


【新式】食事：ロネークステーキHQ　工数9175　品質14588　必要CP：739　
/ac "確信" <wait.3>
/ac "ヴェネレーション" <wait.2>
/ac "長期倹約" <wait.2>
/ac "下地作業" <wait.3>
/ac "下地作業" <wait.3>
/ac "下地作業" <wait.3>
/ac "イノベーション" <wait.2>
/ac "下地加工" <wait.3>
/ac "加工" <wait.3>
/ac "中級加工" <wait.3>
/ac "上級加工" <wait.3>
/ac "パーフェクトメンド" <wait.3>
/ac "倹約加工" <wait.3>
/ac "イノベーション" <wait.2>
/echo Macro #1 complete <se.1>

/ac "精密作業" <wait.3>
/ac "加工" <wait.3>
/ac "中級加工" <wait.3>
/ac "上級加工" <wait.3>
/ac "匠の絶技" <wait.3>
/ac "グレートストライド" <wait.2>
/ac "イノベーション" <wait.2>
/ac "下地加工" <wait.3>
/ac "匠の神業" <wait.3>
/ac "グレートストライド" <wait.2>
/ac "ビエルゴの祝福" <wait.3>
/ac "ヴェネレーション" <wait.2>
/ac "模範作業" <wait.3>
/ac "模範作業" <wait.3>
/echo Macro #2 complete <se.14>


ご意見ご指摘あればよろしくお願いします。